Components All New MacOS Windows Linux iOS
Examples Mac & Win Server Client Guides Statistic FMM Blog Deprecated Old

FM.InsertRecord

Inserts a new record in a table in one line.

Component Version macOS Windows Linux Server iOS SDK
FM FMSQL 5.1 ✅ Yes ✅ Yes ✅ Yes ✅ Yes ✅ Yes
MBS( "FM.InsertRecord"; FileName; TableName; FieldName...; FieldValue... )   More

Parameters

Parameter Description Example
FileName The file name of where the table is inside. Can be empty to look for the table in all files.

Using a table in another database file may require you adding the other file as an external data source and adding the external table to your relationship graph to grant access.		 Get(FileName)
TableName The name of the table to insert record into.
Can be ID of table, so we lookup name by ID.
Can be result of GetFieldName() function as we remove field name automatically.		 "Assets"
FieldName... A field name to set.
Can be ID of field, so we lookup name by ID.
Can be result of GetFieldName() function as we remove table name automatically.		 "Model"
FieldValue... A field value to use for setting the field in the parameter before.
Data type of parameter must match the data type of the field.		 "Test"

Result

Returns OK or error.

Description

Inserts a new record in a table in one line.
You pass to this function table name (and optional filename).
Then you pass one pair of field name and value for each field you like to set in the new record.

As we can't know the new ID assigned for the record, you can help yourself by passing in an UUID for a field and later select that to get the auto assigned primary key (or have the UUID be the primary key, so you don't need a query).

See also FM.UpdateRecord to update a record and FM.InsertOrUpdateRecord to update or insert record.
With plugin version 7.2 or later, you can specify fields and table via IDs and the plugin will lookup them for you at runtime. Table IDs and table names must be unique across all open files for this to work correctly.

You can use FM.ExecuteSQL.LastSQL function to see later what SQL was created and run.
The SQL functions in FileMaker do not trigger OnWindowsTransaction script trigger.

Does not take part in transactions in FileMaker. Changes are made directly to the database, so you can't revert them later with Revert Transaction script step.

This function takes variable number of parameters. Pass as much parameters as needed separated by the semicolon in FileMaker.
Please repeat FieldName and FieldValue parameters as often as you need.

Examples

Insert a record into Assets table:

MBS("FM.InsertRecord"; ""; "Assets"; "Model"; "TestModell"; "Item"; "MyItem"; "Serial Number"; "1234"; "In Service Date"; GetAsDate( "31.05.1996"))

Insert a record with 5 fields:

MBS("FM.InsertRecord"; $filename; $tablename; $field1; $value1; $field2; $value2; $field3; $value3; $field4; $value4; $field5; $value5)

Insert with table and field ID instead of names:

Set Variable [ $r ; Value: MBS("FM.InsertRecord"; Get(FileName); "1065089"; "3"; "Hello") ]

Insert with using GetFieldName for field names:

MBS( "FM.InsertRecord"; ""; "Contacts";
GetFieldName ( Contacts::First ); "Joe";
GetFieldName ( Contacts::Last ); "Miller";
GetFieldName ( Contacts::Group ); "Best Customers" )

Build dynamically the evaluate statement with parameters:

# Our input parameters with field name list
Set Variable [ $FieldNames ; Value: FieldNames ( Get(FileName) ; Get(LayoutName) ) ]
#
# We build parameters for our Evaluate call
Set Variable [ $Params ; Value: "" ]
Set Variable [ $ParamIndex ; Value: 0 ]
#
Set Variable [ $ParamIndex ; Value: $ParamIndex + 1 ]
Set Variable [ $P[$ParamIndex] ; Value: Get(FileName) ]
Set Variable [ $Params ; Value: $Params & "; $P[" & $ParamIndex & "]" ]
#
Set Variable [ $ParamIndex ; Value: $ParamIndex + 1 ]
Set Variable [ $P[$ParamIndex] ; Value: Get(LayoutTableName) ]
Set Variable [ $Params ; Value: $Params & "; $P[" & $ParamIndex & "]" ]
#
# We loop over field list
Set Variable [ $Count ; Value: ValueCount ( $FieldNames ) ]
Set Variable [ $FieldIndex ; Value: 0 ]
Set Variable [ $Types ; Value: "" ]
#
Loop
    # get field name and value
    Set Variable [ $FieldIndex ; Value: $FieldIndex + 1 ]
    Set Variable [ $Fieldname ; Value: GetValue($FieldNames; $FieldIndex) ]
    Set Variable [ $Value ; Value: GetField ( $Fieldname) ]
    #
    # Check typ to filter fields we don't want
    Set Variable [ $Typ ; Value: FieldType ( Get(FileName) ; $Fieldname ) ]
    If [ Position ( $Typ; "Global"; 1; 1 ) ≥ 1 or Position ( $Typ; "Summary"; 1; 1 ) ≥ 1 or Position($Typ; "storedCalc"; 1; 1) ≥ 1 or $Fieldname = "ID" ]
        # ignore global, statistic and unsaved formula field
        // Show Custom Dialog [ "Typ" ; $FieldName & ": " & $typ ]
    Else
        # We store in $P[] our parameters for evaluate and in $Params the parameters for Evaluate
        Set Variable [ $Types ; Value: $Types & ¶ & $FieldName & ": " & $Typ ]
        Set Variable [ $ParamIndex ; Value: $ParamIndex + 1 ]
        Set Variable [ $P[$ParamIndex] ; Value: $Fieldname ]
        Set Variable [ $Params ; Value: $Params & "; $P[" & $ParamIndex & "]" ]
        Set Variable [ $ParamIndex ; Value: $ParamIndex + 1 ]
        Set Variable [ $P[$ParamIndex] ; Value: $Value ]
        Set Variable [ $Params ; Value: $Params & "; $P[" & $ParamIndex & "]" ]
    End If
    #
    Exit Loop If [ $FieldIndex = $count ]
End Loop
#
# now build Evaluate command and show it
// Show Custom Dialog [ "Types" ; $Types ]
Set Variable [ $Function ; Value: "FM.InsertRecord" ]
Set Variable [ $command ; Value: "MBS($Function" & $params & ")" ]
Show Custom Dialog [ "Command" ; $Command ]
If [ Get ( LastMessageChoice ) = 1 ]
    # And run it!
    Set Variable [ $result ; Value: Evaluate($Command) ]
    Show Custom Dialog [ "Result" ; $Result ]
End If

Insert with automatic table name:

MBS("FM.InsertRecord";
""; // empty for current file
""; // empty as given with first field
GetFieldName ( Anlagen::Seriennummer ); // field name queried
"12345") // and value

CountScriptCall custom function:

If($$LogScriptCalls;
Let ( [
FileName = Get(FileName);
ScriptName = Get(ScriptName);

// try to insert new record
r = MBS( "FM.InsertRecord"; FileName; "ScriptCallCounter"; "Counter"; 1; "ScriptName"; ScriptName; "FileName"; FileName );

// r shows OK or "[MBS] ERROR: (504): Field failed unique value validation test" in case of duplicate

// check for error: 504
p = Position ( r ; "(504)" ; 1 ; 1 );

// update existing call on error
r = If( p > 0; MBS( "FM.ExecuteFileSQL"; FileName; "UPDATE \"ScriptCallCounter\" SET \"Counter\" = \"Counter\" + 1 WHERE \"ScriptName\" = ? AND \"FileName\" = ?"; 9; 13; ScriptName; FileName ); r)

]; r ); "")

LogFunctionCall custom function:

If($$LogScriptCalls; Let ( [

// query some values about current context
FileName = Get(FileName);
ScriptName = Get(ScriptName);
TableName = Get(LayoutTableName);
AccountName = Get(AccountName);
LayoutName = Get(LayoutName);
UserName = Get(UserName);
IP = Get(SystemIPAddress);
ScriptParameter = Get(ScriptParameter);

// make an unique key for later
$ScriptCallID = Get(UUID);

// and build call stack
$$CallStack = $$CallStack & ScriptName & ¶;

// now log it.
r = MBS( "FM.InsertRecord"; FileName; "ScriptCallLog";
"ScriptCallID"; $ScriptCallID;
"ScriptName"; ScriptName;
"FileName"; FileName;
"TableName"; TableName;
"LayoutName"; LayoutName;
"AccountName"; AccountName;
"UserName"; UserName;
"IP"; IP;
"ScriptParameter"; GetAsText(ScriptParameter);
"CallStack"; $$CallStack;
"StartTime"; Get ( CurrentTimestamp ))

]; r ); "")

LogFunctionResult custom function:

If( not IsEmpty($ScriptCallID); Let ( [

// remove us from call stack
$$CallStack = LeftValues ( $$CallStack ; ValueCount ( $$CallStack ) - 1 );

// now updat entry in log to show result.
FileName = Get(FileName);

r = MBS( "FM.ExecuteFileSQL"; FileName; "UPDATE \"ScriptCallLog\" SET \"ScriptResult\" = ?, \"EndTime\" = ? WHERE \"ScriptCallID\" = ?"; 9; 13; GetAsText( Result ); Get(CurrentTimestamp); $ScriptCallID )

]; Result ); Result)

Use an insert ID to get the primary key of a new records:

Set Variable [ $InsertID ; Value: Get(UUIDNumber) ]
Set Variable [ $r ; Value: MBS("FM.InsertRecord"; Get(FileName); "Assets";
    "Name"; "Test";
    "Vendor"; "Company Ltd.";
    "InsertID"; $InsertID) ]
Set Variable [ $primaryKey ; Value: MBS( "FM.ExecuteFileSQLValue"; Get(FileName); "SELECT \"PrimaryKey\" FROM \"Assets\" WHERE \"InsertID\" = ?"; $InsertID) ]
Show Custom Dialog [ "New primary key: " & $primaryKey ]

See also

Release notes

Example Databases

Blog Entries

This function checks for a license.

Created 24th April 2015, last changed 20th August 2024


FM.InsertOrUpdateRecordQuery - FM.InsertRecordCSV