DynaPDF.Optimize

Optimizes PDF.

Parameters

Parameter	Description	Example	Flags
PDF	The PDF reference.	$pdf
Flags	The flags to use. Can be a number with values from dynapdf documentation, see table on this page.	"ConvertAllColors,ScaleImages"	Optional
Min1BitRes	Minimum resolution before scaling for one bit images. Default is 100. Can be zero to disable.	200	Optional
MinGrayRes	Minimum resolution before scaling for gray images. Default is 100. Can be zero to disable.	200	Optional
MinColorRes	Minimum resolution before scaling for color images. Default is 100. Can be zero to disable.	200	Optional
Res1BitImages	Resolution for 1 bit black & white images. Default is 150.	150	Optional
ResGrayImages	Resolution for gray images. Default is 150.	150	Optional
ResColorImages	Resolution for images with more than one color channel. Default is 150.	150	Optional
Filter1Bit	Filter for black & white images. Can be Flate, JPEG, CCITT3, CCITT4, LZW, FlateBW or JP2K. Default is JPEG.	"JPEG"	Optional
FilterGray	Filter for gray images. Can be Flate, JPEG, CCITT3, CCITT4, LZW, FlateBW or JP2K. Default is JPEG.	"JPEG"	Optional
FilterColor	Filter for multi-channel images. Can be Flate, JPEG, CCITT3, CCITT4, LZW, FlateBW or JP2K. Default is JPEG.	"JPEG"	Optional
JPEGQuality	JPEG quality. Default is 80.	80	Optional
JP2KQuality	JPEG 2000 quality Default is 80.	80	Optional
MinLineWidth	Minimum line width for lines. Zero means no hair line removal.	0	Optional

Result

Returns OK or error.

Description

See also Optimize function in DynaPDF manual.

Examples

Optimize by scaling images:

MBS( "DynaPDF.Optimize"; $pdf; "ScaleImages,IgnoreICCBased" )

Optimize with defaults:

MBS( "DynaPDF.Optimize"; $pdf)

Merge PDFs and optimize:

# Initialize DynaPDF if needed
If [ MBS("DynaPDF.IsInitialized") ≠ 1 ]
    Perform Script [“InitDynaPDF”]
End If
#Clear current PDF document
Set Variable [$pdf; Value:MBS("DynaPDF.New")]
#For writing to file instead of container, pass path here:
// Set Variable [$r; Value:MBS("DynaPDF.OpenOutputFile"; $pdf; "/Users/cs/Desktop/test.pdf")]
#Load PDF from container
Go to Record/Request/Page [First]
Set Variable [$destPage; Value:1]
Loop
    #Read from file
    // Set Variable [$r; Value:MBS("DynaPDF.OpenPDFFromFile"; $pdf; "/Users/cs/Desktop/input.pdf")]
    #or container
    Set Variable [$r; Value:MBS("DynaPDF.OpenPDFFromContainer"; $pdf; Merge PDFs::InputPDF)]
    #Import all pages
    Set Variable [$r; Value:MBS("DynaPDF.ImportPDFFile"; $pdf; $destpage)]
    If [GetAsNumber($r) >0]
        Set Variable [$destPage; Value:$r+1]
    End If
    Go to Record/Request/Page [Next; Exit after last]
End Loop
#Repair & Optimize PDF
Set Variable [$r; Value:MBS("DynaPDF.Optimize"; $pdf)]
#Save to container
Set Field [Merge PDFs::FinalPDF; MBS("DynaPDF.Save"; $pdf; "Merged.pdf")]
Set Variable [$r; Value:MBS("DynaPDF.Release"; $pdf)]

Custom function for easy optimization:

# Custom Function OptimizePDF(InputPDF)
#
# Optimizes PDF and returns either new one or old one in case of error.

Let ([
PDF = MBS("DynaPDF.New");
OpenResult = MBS("DynaPDF.OpenPDFFromContainer"; PDF; InputPDF);
OpenError = MBS("IsError");
ImportResult = MBS("DynaPDF.ImportPDFFile"; PDF);
ImportError = MBS("IsError");
Options = "FlattenLayers DeleteInvPaths ScaleImages NewLinkNames DeletePrivateData IgnoreZeroLineWidth DeleteAlternateImages DeleteThumbnails";
OptimizeResult = MBS("DynaPDF.Optimize"; PDF; Options; 50; 50; 50; 150; 150; 150; "JPEG"; "JPEG"; "JPEG");
OptimizeError = MBS("IsError");
OutputPDF = MBS("DynaPDF.Save"; PDF; GetAsText(InputPDF));
SaveError = MBS("IsError");
ReleaseError = MBS("DynaPDF.Release"; PDF);

Result = If(
    // all okay?
    OpenError = 0 and ImportError = 0 and OptimizeError = 0 and SaveError = 0 and MBS( "Container.GetSize"; OutputPDF; "PDF " ) > 0;
    // than return new PDF
    OutputPDF;
    // return old PDF
    InputPDF)
 
];
result )

Optimizes with files input/output:

# Initialize DynaPDF if needed
If [ MBS("DynaPDF.IsInitialized") ≠ 1 ]
    Perform Script [ “InitDynaPDF” ]
End If
# Clear current PDF document
Set Variable [ $pdf ; Value: MBS("DynaPDF.New") ]
# Load PDF from container
Set Variable [ $r ; Value: MBS("DynaPDF.OpenPDFFromFile"; $pdf; "C:\Users\Christian\Desktop\171206Y_C24555_Annie_PDFs\171206Y_C24555_Annie_WOprice.pdf") ]
Set Variable [ $r ; Value: MBS("DynaPDF.OpenOutputFile"; $pdf; "C:\Users\Christian\Desktop\171206Y_C24555_Annie_PDFs\171206Y_C24555_Annie_WOprice.optimized.pdf") ]
Set Variable [ $r ; Value: MBS("DynaPDF.ImportPDFFile"; $pdf; 1) ]
# Optimize
Set Variable [ $r ; Value: MBS("DynaPDF.Optimize"; $pdf; "FlattenLayers¶DeleteInvPaths¶ScaleImages¶NewLinkNames¶DeletePrivateData¶IgnoreZeroLineWidth¶DeleteAlternateImages¶DeleteThumbnails"; 50; 50; 50; 150; 150; 150; "JPEG"; "JPEG"; "JPEG") ]
# Save
Set Field [ Optimize PDF::Output PDF ; MBS("DynaPDF.Save"; $pdf; "Merged.pdf") ]
Set Variable [ $r ; Value: MBS("DynaPDF.Release"; $pdf) ]

Convert all colors to CMYK:

Set Variable [ $r ; Value: MBS("DynaPDF.InitColorManagement"; $pdf; "DeviceCMYK";
3;
"/System/Library/ColorSync/Profiles/Generic Gray Profile.icc";
"/System/Library/ColorSync/Profiles/Generic RGB Profile.icc";
"/System/Library/ColorSync/Profiles/Generic CMYK Profile.icc";
"/System/Library/ColorSync/Profiles/Generic CMYK Profile.icc"
)]
Set Variable [ $r ; Value: MBS("DynaPDF.Optimize"; $pdf; "ConvertToCMYK") ]

See also

• DynaPDF.ImportPDFFile
• DynaPDF.MarkTemplateAsWatermark
• DynaPDF.OpenOutputFile
• DynaPDF.OpenPDFFromContainer
• DynaPDF.OpenPDFFromFile
• DynaPDF.Parser.Create
• DynaPDF.Parser.WriteToPage
• DynaPDF.Release
• DynaPDF.Save
• IsError

Release notes

• Version 11.2
  • Fixed an issue with DynaPDF.Optimize complaining about no open output file.
• Version 9.3
  • Added flags for DynaPDF.Optimize: ConvertToGray, ConvertToRGB, ConvertToCMYK and ReplaceJP2KWithJPEG.
• Version 9.0
  • Changed DynaPDF.Optimize to use in memory flag by default unless you change it.
• Version 8.2
  • Added checks to DynaPDF.Optimize, DynaPDF.Print and DynaPDF.Save to complain if no pages are in document.

Example Databases

• DynaPDF/Optimize PDF

Blog Entries

• Unlocking the Power of PDFs in FileMaker with DynaPDF and the MBS FileMaker Plugin
• Can FileMaker do that?
• MBS FileMaker Plugin, version 13.3pr3
• Things you can do with DynaPDF
• DynaPDF Optimize command
• MBS FileMaker Plugin 9.3 - More than 5900 Functions In One Plugin
• Combine MBS functions to automate processes in FileMaker
• Custom function to optimize PDF in FileMaker via DynaPDF
• MBS FileMaker Plugin 6.0 for OS X/Windows
• Optimize PDF Script

This function checks for a license.

Created 18th January 2016, last changed 25th September 2024

DynaPDF.OpenTagEx - DynaPDF.PageLink