Components All New MacOS Windows Linux iOS
Examples Mac & Win Server Client Guides Statistic FMM Blog Deprecated Old

ImageCapture.SetParameter

Sets a parameter for current scanner functional device.

Component Version macOS Windows Linux Server iOS SDK
ImageCapture 6.4 ✅ Yes ❌ No ❌ No ❌ No ❌ No
MBS( "ImageCapture.SetParameter"; Selector; Value )   More

Parameters

Parameter Description Example
Selector The value to set. "documentName"
Value The value to set.

Result

Returns OK or error.

Description

Sets a parameter for current scanner functional device.

SelectorDescriptionExample
bitDepthThe bit depth to use when performing the final scan. This will always be one of the supported bit depths.8
documentNameThe document name.„Scan"
documentTypeCurrent document type.„A4"
documentUTIThe document UTI. Can be set using JPEG, JPEG2000, PDF, TIFF or PNG.„JPEG“
downloadsDirectoryThe downloads directory. If you pass „temp“, we use the user’s temp folder.„/Users/cs/Desktop“
maxMemoryBandSizeThe total maximum band size requested when performing a memory based transfer.
measurementUnitCurrent measurement unit. Can be Inches, Centimeters, Picas, Points, Twips or Pixels.„Inches"
overviewResolutionOverview image resolution. Value assigned to this will be constrained by resolutions allowed by the device.
resolutionCurrent scan resolution. This will always be one of the supported resolution values.300
thresholdForBlackAndWhiteScanningThreshold value to be used when performing a scan in black & white. This value should be from 0 to 255.127
transferModeThe transfer mode for scanned document. Can be File or Memory, but Plugin only supports File.„File"
usesThresholdForBlackAndWhiteScanningIndicates if this functional unit uses threshold value to be used when performing a scan in black & white.1
duplexScanningEnabledIndicates whether duplex scanning is enabled.1
scaleFactorCurrent scale factor. This will always be one of the supported scale factor values.100
pixelDataTypeThe pixel data type. Can be BW, Gray, RGB, Palette, CMY, CMYK, YUV, YUVK or CIEXYZ."RGB"
scanAreaOrientationDesired orientation of the scan area. This property along with scanArea describes the area to be scanned. 1 for Normal, 2 Flipped horizontally, 3 Rotated 180°, 4 Flipped vertically, 5. Rotated 90° CCW and flipped vertically, 6 Rotated 90° CCW, 7 Rotated 90° CW and flipped vertically, 8 Rotated 90° CW.1
oddPageOrientationDesired orientation of the odd pages of the scanned document.1
evenPageOrientationDesired orientation of the even pages of the scanned document.1
scanAreaPass 4 parameters with X, Y, Width and Height to define scan.

For scan area, please pass x, y, width and height as separate parameters.
Default folder for files is temporary folder.

List of valid document types: Default, A4, B5, USLetter, USLegal, A5, ISOB4, ISOB6, USLedger, USExecutive, A3, ISOB3, A6, C4, C5, C6, 4A0, 2A0, A0, A1, A2, A7, A8, A9, 10, ISOB0, ISOB1, ISOB2, ISOB5, ISOB7, ISOB8, ISOB9, ISOB10, JISB0, JISB1, JISB2, JISB3, JISB4, JISB6, JISB7, JISB8, JISB9, JISB10, C0, C1, C2, C3, C7, C8, C9, C10, USStatement, BusinessCard, E, 3R, 4R, 5R, 6R, 8R, S8R, 10R, S10R, 11R, 12R, S12R, 110, APSH, APSC, APSP, 135, MF, LF.

Examples

Set scan area to physical size:

Set Variable [$physicalWidth; Value:MBS("ImageCapture.GetParameter"; "physicalWidth")]
Set Variable [$physicalHeight; Value:MBS("ImageCapture.GetParameter"; "physicalHeight")]
Set Variable [$r; Value:MBS("ImageCapture.SetParameter"; "scanArea"; 0; 0; $physicalWidth; $physicalHeight)]

Set to US Letter format:

MBS("ImageCapture.SetParameter"; "documentType"; "USLetter")

Set document name:

MBS("ImageCapture.SetParameter"; "documentName"; "Scan")

Set resolution to 300 dpi:

MBS("ImageCapture.SetParameter"; "resolution"; 300)

Set to scan 8 bit RGB picture:

Set Variable [$r; Value:MBS("ImageCapture.SetParameter"; "bitDepth"; 8)]
Set Variable [$r; Value:MBS("ImageCapture.SetParameter"; "pixelDataType"; "RGB")]

Set JPEG image type:

Set Variable [$r; Value:MBS("ImageCapture.SetParameter"; "documentUTI"; "jpeg")]

Use temporary folder for temp files:

Set Variable [$r; Value:MBS("ImageCapture.SetParameter"; "downloadsDirectory"; "temp")]

Set scan area:

MBS( "ImageCapture.SetParameter"; "scanArea"; $x; $y; $w; $h )

Enable duplex:

MBS("ImageCapture.SetParameter"; "duplexScanningEnabled"; 1)

Set to A4 format:

MBS("ImageCapture.SetParameter"; "documentType"; "A4")

Switch to color or gray:

If [ $gray ]
    Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "bitDepth"; 8) ]
    Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "pixelDataType"; "Gray") ]
Else
    Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "bitDepth"; 8) ]
    Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "pixelDataType"; "RGB") ]
End If

Run scan with duplex:

# set parameters
Set Variable [ $physicalWidth ; Value: MBS("ImageCapture.GetParameter"; "physicalWidth") ]
Set Variable [ $physicalHeight ; Value: MBS("ImageCapture.GetParameter"; "physicalHeight") ]
Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "documentType"; "A4") ]
Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "documentName"; "Scan") ]
Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "resolution"; 300) ]
Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "bitDepth"; 8) ]
Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "pixelDataType"; "RGB") ]
Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "documentUTI"; "jpeg") ]
Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "downloadsDirectory"; "temp") ]
Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "duplexScanningEnabled"; 1) ]
Set Variable [ $r ; Value: MBS("ImageCapture.SetParameter"; "scanArea"; 0; 0; $physicalWidth; $physicalHeight) ]
Set Variable [ $p ; Value: MBS("ProgressDialog.Reset") ]
Set Variable [ $p ; Value: MBS("ProgressDialog.SetTitle"; "Scanning" ) ]
Set Variable [ $p ; Value: MBS("ProgressDialog.SetBottomText"; "" ) ]
Set Variable [ $p ; Value: MBS("ProgressDialog.SetTopText"; "Scan from Flatbed scanner." ) ]
Set Variable [ $p ; Value: MBS("ProgressDialog.SetButtonCaption"; "Cancel" ) ]
Set Variable [ $p ; Value: MBS("ProgressDialog.SetProgress"; -1 ) ]
Set Variable [ $p ; Value: MBS("ProgressDialog.Show" ) ]
Set Variable [ $r ; Value: MBS("ImageCapture.RequestScan") ]
Set Variable [ $p ; Value: MBS("ProgressDialog.Hide" ) ]
If [ MBS("iserror") ]
    Show Custom Dialog [ "Failed start scan" ; MBS("Text.RemovePrefix"; $r; "[MBS] ") ]
    Exit Script [ Text Result: ]
End If
#
# read images
Pause/Resume Script [ Duration (seconds): ,1 ]
Set Variable [ $Paths ; Value: MBS("ImageCapture.ImagePaths") ]
If [ Length ( $Paths ) > 0 ]
    Set Variable [ $Count ; Value: ValueCount ( $Paths ) ]
    If [ $Count > 0 ]
        Set Variable [ $Index ; Value: 1 ]
        Loop
            Set Variable [ $Path ; Value: GetValue($Paths; $index) ]
            New Record/Request
            Set Field [ Images::Image ; MBS("Container.ReadFile"; $path) ]
            Set Variable [ $r ; Value: MBS( "Files.Delete"; $Path ) ]
            Commit Records/Requests [ With dialog: Off ]
            Set Variable [ $Index ; Value: $index + 1 ]
            Exit Loop If [ $index > $count ]
        End Loop
    End If
End If

Set PNG image type:

Set Variable [$r; Value:MBS("ImageCapture.SetParameter"; "documentUTI"; "png")]

Set to scan black and white picture:

Set Variable [$r; Value:MBS("ImageCapture.SetParameter"; "bitDepth"; 1)]
Set Variable [$r; Value:MBS("ImageCapture.SetParameter"; "pixelDataType"; "BW")]

Set PDF image type:

Set Variable [$r; Value:MBS("ImageCapture.SetParameter"; "documentUTI"; "pdf")]

See also

Release notes

Example Databases

Blog Entries

This function checks for a license.

Created 11st September 2016, last changed 22nd November 2022


ImageCapture.SetItemsAddedScript - ImageCapture.Thumbnail